* @START   MAKPO - HAþAìO ðPOçPAMMù                                     TART0001
* * * ðOCìEäHññ KOPPEKTéPOBKA:  äATA 28.01.89   BPEMñ 05.27   *  æOKõC  TART0002
*  ìEHéHçPAä éBã çõT  OTä. 07 ìATùûKO                   T: 310-98-12    TART0003
         MACRO                                                          TART0004
&NAME    @START &PRINT=NOGEN,&SAVE=(14,12),&BASE=15,&RPARM=,&R0=,&DEV=,*TART0005
               &ID=,&DATE=                                              TART0006
         GBLB  &DSADSEC                                                 TART0007
         LCLA  &I,&IDL                                                  TART0008
         LCLC  &IDENT                                                   TART0009
         AIF   ('&PRINT' EQ '').CSECT                                   TART0010
        PRINT &PRINT                                                    TART0011
.CSECT   ANOP                                                           TART0012
&NAME    CSECT                                                          TART0013
.ID      AIF   ('&ID&DATE' EQ '').SAVE                                  TART0014
         AIF   ('&ID' EQ '').DATE                                       TART0015
&IDL     SETA  K'&ID                                                    TART0016
&IDENT   SETC  '&ID'                                                    TART0017
         AIF   ('&ID'(1,1) NE '''').ID1                                 TART0018
&IDL     SETA  &IDL-2                                                   TART0019
&IDENT   SETC  '&ID'(2,&IDL)                                            TART0020
         AGO   .DATE                                                    TART0021
.ID1     AIF   ('&ID' NE '*').DATE                                      TART0022
&IDL     SETA  K'&NAME                                                  TART0023
&IDENT   SETC  '&NAME'                                                  TART0024
.DATE    AIF   ('&DATE' EQ '').ID2                                      TART0025
&IDL     SETA  &IDL+9                                                   TART0026
&IDENT   SETC  '&IDENT &SYSDATE'                                        TART0027
.ID2     ANOP                                                           TART0028
&IDL2    SETA  (&IDL+2)/2*2                                             TART0029
         B     4+&IDL2.(0,15)      BRANCH AROUND IDENTIFIER             TART0030
         DC    AL1(&IDL)           LENGTH OF IDENTIFIER                 TART0031
         DC    CL&IDL'&IDENT'                                IDENTIFIER TART0032
.SAVE    AIF   ('&SAVE' EQ '').BASE                                     TART0033
         SAVE  &SAVE                                                    TART0034
.BASE    AIF   (&I GE N'&BASE).RPARM                                    TART0035
         AIF   (&I NE 0).BASE2                                          TART0036
         AIF   ('&BASE(1)' EQ '15').USING                               TART0037
         LR    &BASE(1),15       LOAD BASE REGISTER                     TART0038
         AGO   .USING                                                   TART0039
.BASE2   LA    &BASE(&I+1),4095(&BASE(&I))  LOAD BASE REGISTER          TART0040
         LA    &BASE(&I+1),1(&BASE(&I+1))   LOAD BASE REGISTER          TART0041
.USING  USING &NAME+(&I)*4096,&BASE(&I+1)                               TART0042
&I       SETA  &I+1                                                     TART0043
         AGO   .BASE                                                    TART0044
.RPARM   AIF   ('&RPARM' EQ '').R0                                      TART0045
         LR    &RPARM,1          KEEP REGISTER 1                        TART0046
.R0      AIF   ('&R0' EQ '').DSA                                        TART0047
         LR    &R0,0             KEEP REGISTER 0                        TART0048
.DSA     AIF   (NOT &DSADSEC).LOCTRS                                    TART0049
         BAL   1,*+4             LOAD R1 NEGATIVE TO SHOW GETMAIN       TART0050
         L     0,=A(@DSASIZE)    LOAD DINAMIC STORAGE AREA SIZE         TART0051
         SVC   10                GETMAIN SVC                            TART0052
         ST    13,4(0,1)                                                TART0053
         ST    1,8(0,13)                                                TART0054
         LR    13,1                                                     TART0055
        USING DSA,13                                                    TART0056
.LOCTRS  ANOP                                                           TART0057
SUBPGMS  LOCTR                                                          TART0058
CONSTD   LOCTR                                                          TART0059
CONSTF   LOCTR                                                          TART0060
CONSTH   LOCTR                                                          TART0061
&NAME    LOCTR                                                          TART0062
.END     MEND                                                           TART0063